[Batch] Codigo bastante interesante (Efecto)

En esta ocasión hablaremos un poco mas sobre batch :

Para los newbies como yo y muchos mas este "efecto" lo haciamos un poco (muy) diferente al codigo que mostrare hoy, que es el "efecto de maquina de escribir".

Asi lo conocia yo:

Código

@echo off
color a
cls
echo 2
PING 1.1.1.1 -n 1 -w 10>NUL
cls
echo 2F
PING 1.1.1.1 -n 1 -w 10>NUL
cls
echo 2Fa
PING 1.1.1.1 -n 1 -w 10>NUL
cls
echo 2Fac
PING 1.1.1.1 -n 1 -w 10>NUL
cls
echo 2Fac3
PING 1.1.1.1 -n 1 -w 10>NUL
cls
echo 2Fac3R
PING 1.1.1.1 -n 1 -w 10>NUL
pause>nul & exit

Hace poco que he visto este nuevo code en un post por CEH:

Autor: Carlitos.dll

Código

@echo off
mode con cols=100
mode con lines=20

call:tpwrtr CarlitoS.dll presenta:
call:sleep 2
echo.
call:tpwrtr el efecto maquina de escribir ...
echo.
echo.
call:tpwrtr OpenBSD es un sistema operativo libre tipo Unix, multiplataforma, basado en 4.4BSD.
call:sleep 3
echo.
call:tpwrtr Es un descendiente de NetBSD, con un foco especial en la seguridad y la criptografia.
echo.

pause>nul
goto:eof


:tpwrtr
set palabra=%*
if not defined palabra (goto:eof)
set palabra=%palabra: =_%
call:length %palabra%
set /a contt=0
:loopt
call :tpwrtr1 %%palabra:~%contt%,1%%
set /a contt +=1
if %contt% leq %tam% (goto:loopt)
goto:eof
:tpwrtr1
set char=%1
if [%char%]==[_] (set char= )
<nul (set /p msg=%char%)
ping -n 1 127.0.0.0 -w 1>nul 2>&1
goto:eof
:length
set argl=%*
if not defined argl (goto :eof)
set wordl=%argl%
set /a contl=0
:loopl
if not defined wordl (goto endl)
set wordl=%wordl:~1%
set /a contl +=1
goto loopl
:endl
set tam=%contl%
goto :eof

:sleep
if "%1"=="" (goto :eof)
set /a limit=0
set /a limit=%1
if %limit% LEQ 0 (goto :eof)
set /a cont=0
:time
set mirror1=%time:~-4,1%
:increment
set mirror2=%time:~-4,1%
if not %mirror2%==%mirror1% (goto count)
goto increment
:count
set /a cont +=1
if "%cont%"=="%limit%" (goto :eof)
goto time
goto :eof

Como pueden ver es un code avanzado pero bastante eficaz en lo que hace, aqui tienen la fuente del post donde me entere, en el pueden encontrar mas codes.